home *** CD-ROM | disk | FTP | other *** search
/ PC Media 7 / PC MEDIA CD07.iso / evil / rsys.bat < prev    next >
Encoding:
DOS Batch File  |  1989-07-26  |  7.6 KB  |  196 lines
  1. Echo off
  2. REM *************************************************************************
  3. REM Robosystems Batch File                Copyright (c) 1989 Robocom Ltd
  4. REM *************************************************************************
  5. REM ROBOKILL     Environment variable containing the command to remove the       
  6. REM         current memory resident graphics driver
  7. REM ROBOPARAM     Environment variable containing the parameter that is to 
  8. REM        be passed to the next program from the suite to be run
  9. REM ROBOINPUT     Environment variable containing the command for loading
  10. REM        an input device
  11. REM Clear all parameter environment variables
  12. REM COLOURS - the setup program for high res displays is run if present
  13. REM *************************************************************************
  14. cls                    :Clear screen
  15. set ROBOPARAM=
  16. set ROBOINPUT=
  17. set ROBOKILL=
  18. if not exist rc_con.exe goto end    :Test for system menu program
  19. if exist colours.exe COLOURS
  20. REM *************************************************************************
  21. REM INSTALLATION AND SYSTEM MENU PROGRAM
  22. REM Remove any resident graphics program the command for which is in ROBOKILL
  23. REM Clear the graphics driver killing environment variable ROBOKILL
  24. REM set input device including path if networked
  25. REM Run Installation or System Menu program
  26. REM RC_CON exit codes allow:    Exit to DOS
  27. REM                       Load ROBOINPUT input device and run RoboDATA
  28. REM                       Load no input device and run RoboDATA
  29. REM                       Load ROBOINPUT input device and run RoboBUILD
  30. REM                       Load no input device and run RoboBUILD
  31. REM                       Load ROBOINPUT input device and run RoboCAD
  32. REM                       Load no input device and run RoboCAD
  33. REM                       Load ROBOINPUT input device and run RoboSOLID
  34. REM                       Load no input device and run RoboSOLID
  35. REM                Restart this batch file after installation
  36. REM *************************************************************************
  37. :system_menu
  38. %ROBOKILL%
  39. set ROBOKILL=
  40. set ROBOINPUT=RC_EXEC INP_DEV.BAT
  41. if exist %RCAD_MACHINE%\INP_DEV.BAT set ROBOINPUT=RC_EXEC %RCAD_MACHINE%\INP_DEV.BAT
  42. RC_CON
  43. if errorlevel 255 goto veryend                :Exit to DOS
  44. if errorlevel 49 goto data
  45. if errorlevel 40 set ROBOINPUT=
  46. if errorlevel 40 goto data                :Run RoboDATA
  47. if errorlevel 39 goto build_config
  48. if errorlevel 30 set ROBOINPUT=
  49. if errorlevel 30 goto build_config            :Run RoboBUILD
  50. if errorlevel 29 goto cad
  51. if errorlevel 20 set ROBOINPUT=
  52. if errorlevel 20 goto cad                :Run RoboCAD
  53. if errorlevel 19 goto solid
  54. if errorlevel 10 set ROBOINPUT=
  55. if errorlevel 10 goto solid                :Run RoboSOLID
  56. RSYS                            :Restart if install
  57. REM *************************************************************************
  58. REM ROBOCAD
  59. REM Remove any resident graphics program the command for which is in ROBOKILL
  60. REM Clear the graphics driver killing environment variable ROBOKILL
  61. REM Load an input device if one has been stored in ROBOINPUT
  62. REM Clear the input device environment variable ROBOINPUT
  63. REM Load the extended character set
  64. REM Run RoboCAD and pass any parameter stored in ROBOPARAM
  65. REM Clear the parameter environment variable ROBOPARAM
  66. REM RoboCAD exit codes allow:    Exit to DOS
  67. REM                       Run RoboSOLID passing data in ROBOPARAM
  68. REM                        Run RoboSOLID without passing data
  69. REM                       Run RoboBUILD passing data in ROBOPARAM
  70. REM                        Run RoboBUILD without passing data
  71. REM                Return to the system menu
  72. REM *************************************************************************
  73. :cad
  74. %ROBOKILL%
  75. set ROBOKILL=
  76. %ROBOINPUT%
  77. set ROBOINPUT=
  78. inp_test
  79. if not errorlevel 1 echo Input device not installed
  80. if not errorlevel 1 goto system_menu
  81. graftabl
  82. echo Loading RoboCAD please wait
  83. ROBOCAD %ROBOPARAM%
  84. set ROBOPARAM=
  85. if errorlevel 255 goto veryend                :Exit to DOS
  86. if errorlevel 41 set ROBOPARAM=cad2dat.rdf
  87. if errorlevel 40 goto data                :Run RoboDATA
  88. if errorlevel 31 set ROBOPARAM=-cad cad2mod.plo
  89. if errorlevel 30 goto build                :Run RoboBUILD
  90. if errorlevel 11 set ROBOPARAM=-cad cad2sol.rdf
  91. if errorlevel 10 goto solid                :Run RoboSOLID
  92. goto system_menu                    :Return to menu
  93. REM *************************************************************************
  94. REM ROBOSOLID
  95. REM Load an input device if one has been stored in ROBOINPUT
  96. REM Clear the input device environment variable ROBOINPUT
  97. REM Clean up the screen
  98. REM Install the low or high resolution graphics driver
  99. REM Store the command for removing the graphics driver in ROBOKILL
  100. REM Run RoboSOLID passing ROBOPARAM
  101. REM RoboSOLID exit codes allow:    Exit to DOS
  102. REM                       Run RoboCAD passing data in ROBOPARAM
  103. REM                        Run RoboCAD without passing data
  104. REM                Return to the system menu
  105. REM ROBOKILL must be run before any environment variables are set or cleared
  106. REM *************************************************************************
  107. :solid
  108. %ROBOINPUT%
  109. set ROBOINPUT=
  110. inp_test
  111. if not errorlevel 1 echo Input device not installed
  112. if not errorlevel 1 goto system_menu
  113. echo Loading RoboSOLID please wait
  114. PRTSCRN /i                        :Clean up the screen
  115. cls
  116. if exist metawndo.exe set ROBOKILL=METAWNDO /k
  117. if exist metarobo.exe set ROBOKILL=METACLR
  118. if exist metawndo.exe METAWNDO
  119. if exist metarobo.exe METAROBO
  120. cls
  121. ROBSOLID %ROBOPARAM%>NUL:
  122. if errorlevel 255 goto veryend                :Exit to DOS
  123. if errorlevel 21 goto data_to_cad
  124. if errorlevel 20 goto to_cad                :Run RoboCAD
  125. %ROBOKILL%
  126. set ROBOKILL=
  127. set ROBOPARAM=
  128. goto system_menu                    :Return to menu
  129. :data_to_cad
  130. %ROBOKILL%
  131. set ROBOKILL=
  132. set ROBOPARAM=-sol sol2cad.rdf
  133. goto cad
  134. :to_cad
  135. %ROBOKILL%
  136. set ROBOKILL=
  137. set ROBOPARAM=
  138. goto cad
  139. REM *************************************************************************
  140. REM ROBOBUILD
  141. REM Delete any transfer files from a previous run
  142. REM Run the graphics driver INT7F
  143. REM Store the command for removing the graphics driver in ROBOKILL
  144. REM Run RoboBUILD and pass any parameter stored in ROBOPARAM
  145. REM RoboBUILD exit codes allow:    Return to system menu
  146. REM                 Run RoboCAD passing data in ROBOPARAM
  147. REM                        Run RoboCAD without passing data
  148. REM *************************************************************************
  149. :build_config
  150. echo Loading RoboBUILD please wait
  151. MOD /C
  152. :build
  153. if exist mod2cad.rdf del mod2cad.rdf
  154. echo Loading RoboBUILD please wait
  155. int7f
  156. set ROBOKILL=CLR7F
  157. if exist modinput.* MODINPUT
  158. MOD %ROBOPARAM%
  159. set ROBOPARAM=
  160. if errorlevel 255 goto system_menu            :Exit to system menu
  161. if not errorlevel 20 goto system_menu
  162. if errorlevel 21 RDFLINK mod2cad.bat
  163. if exist mod2cad.rdf set ROBOPARAM=-mod mod2cad.rdf
  164. goto cad                        :Run RoboCAD
  165. REM *************************************************************************
  166. REM ROBODATA
  167. REM Run RoboDATA and pass any parameter stored in ROBOPARAM
  168. REM Clear the parameter environment variable ROBOPARAM
  169. REM RoboDATA exit codes allow:    Exit to DOS
  170. REM                Return to the system menu
  171. REM *************************************************************************
  172. :data
  173. echo Loading RoboDATA please wait
  174. ATRB %ROBOPARAM%
  175. set ROBOPARAM=
  176. if errorlevel 255 goto veryend                :Exit to DOS
  177. if errorlevel 20 goto cad                :Exit to RoboCAD
  178. goto system_menu                    :Return to menu
  179. REM *************************************************************************
  180. REM Message if installation being tried when current disk is not a:
  181. REM *************************************************************************
  182. :end
  183. echo Please log onto system disk and restart
  184. REM *************************************************************************
  185. REM Remove any memory resident graphics driver
  186. REM Clear all environment variables
  187. REM Exit to DOS 
  188. REM *************************************************************************
  189. :veryend
  190. %ROBOKILL%
  191. set ROBOKILL=
  192. set ROBOINPUT=
  193. set ROBOPARAM=
  194. 
  195.  
  196.